As another analysis option for the mechanical systems you might want to consider setting up separate strategies for the long and short trades respectively for a standard long & short trade system such as the SRS 15 min EDO system. When the equity (profit) curve of the long & short strategy flattens or turns negative you can then determine if either the long or short trades are influencing this. These charts show the curves for the long & short trades standard strategy for the SRS 15 Min EOD system followed by the long trade curve and the short trade curve. As you can see the long & short trade curve has flattened while the long trade curve has turned negative and the short trade curve still has a slight uptrend. In this case you could decide to stop using the system for only the long trades, but still use it for the short trades as opposed to turning the system off completely.

I see that the code didn't get posted so here it is below: The explanation comments are enclosed in {} and won't be executed so you can just copy and paste everything below.

{Trendline Strategy - Long, by Carey Naquin 07-26-09}
 
inputs:
 EntryTLRef (1), ExitTLRef (2), StopLossTLRef (3), StopTLRef (0), TargetTLRef (0);

{The above inputs specify the trendline reference number for the entry,
exit, stop loss, stop, and target trendlines respectively. The trendline
reference numbers can be idenitified by using the Data View Window on the
Chart Analysis screen. They are more easily identified by using different
colors. If there are no existing trendlines, then you can draw them in the
order listed above to use the default values. The entry and either stop loss or exit trendlines are required for this strategy to work while the others are optional. You can still draw them, but the input trendline reference values should be set to 0 if you don't want the strategy to use them.}

variables:
 BDateLE (0), BTimeLE (0), EntryTLValue (0), ValidEntryBar (false),
 BDateLX (0), BTimeLX (0), ExitTLValue (0), ValidExitBar (false),
 BDateSL (0), BTimeSL (0), StopLossTLValue (0), ValidStopLossBar (false),
 BDateSX (0), BTimeSX (0), StopTLValue (0), ValidStopBar (false),
 BDateTX (0), BTimeTX (0), TargetTLValue (0), ValidTargetBar (false),
 ExitMade (false);

{The above variables are programming requirements to perform calculations
and process the statements below at the close of each bar.}

if EntryTLRef > 0 and TL_GetValue (EntryTLRef, Date, Time) > 0 then
 begin
 BDateLE = (TL_GetBeginDate (EntryTLRef));
 BTimeLE = (TL_GetBeginTime (EntryTLRef));
 end;

if ExitTLRef > 0 and TL_GetValue (ExitTLRef, Date, Time) > 0 then
 begin
 BDateLX = (TL_GetBeginDate (ExitTLRef));
 BTimeLX = (TL_GetBeginTime (ExitTLRef));
 end;

if StopLossTLRef > 0 and TL_GetValue (StopLossTLRef, Date, Time) > 0 then
 begin
 BDateSL = (TL_GetBeginDate (StopLossTLRef));
 BTimeSL = (TL_GetBeginTime (StopLossTLRef));
 end;

if StopTLRef > 0 and TL_GetValue (StopTLRef, Date, Time) > 0 then
 begin
 BDateSX = (TL_GetBeginDate (StopTLRef));
 BTimeSX = (TL_GetBeginTime (StopTLRef));
 end;

if TargetTLRef > 0 and TL_GetValue (TargetTLRef, Date, Time) > 0 then
 begin
 BDateTX = (TL_GetBeginDate (TargetTLRef));
 BTimeTX = (TL_GetBeginTime (TargetTLRef));
 end;

{The above statements determine the beginning date and time of the respective
trendlines and sets the initial validation criteria to false for the
respective trendlines. There is also a variable to identify when an exit occurs
so the program will not allow another entry if the strategy is being automated.}

if BarType = 1 then
 begin
 ValidEntryBar = ((Date = BDateLE and Time >= BTimeLE) or Date > BDateLE); 
 ValidExitBar = ((Date = BDateLX and Time >= BTimeLX) or Date > BDateLX);
    ValidStopLossBar = ((Date = BDateSL and Time >= BTimeSL) or Date > BDateSL);
 ValidStopBar = ((Date = BDateSX and Time >= BTimeSX) or Date > BDateSX);
 ValidTargetBar = ((Date = BDateTX and Time >= BTimeTX) or Date > BDateTX);
 end;

{The above statements sets the validation criteria to true for the respective
trendlines if the chart time frame is intraday (BarType = 1) and the date and
time of the bar >= the beginning date and time of the respective trendlines.}

if BarType = 2 then
 begin
 ValidEntryBar = (Date >= BDateLE);
 ValidExitBar = (Date >= BDateLX);
 ValidStopLossBar = (Date >= BDateSL);
 ValidStopBar = (Date >= BDateSX);
 ValidTargetBar = (Date >= BDateTX);
 end;

{The above statements sets the validation criteria to true for the respective
trendlines if the chart time frame is daily (BarType = 2) and the date >= the
beginning date of the respective trendlines.}

if EntryTLRef > 0 then EntryTLValue = TL_GetValue (EntryTLRef, Date, Time);
if ExitTLRef > 0 then ExitTLValue = TL_GetValue (ExitTLRef, Date, Time);
if StopLossTLRef > 0 then StopLossTLValue = TL_GetValue (StopLossTLRef, Date, Time);
if StopTLRef > 0 then StopTLValue = TL_GetValue (StopTLRef, Date, Time);
if TargetTLRef > 0 then TargetTLValue = TL_GetValue (TargetTLRef, Date, Time);

{The above statements calculates the trendline values for each bar.}

if MarketPosition = 0 and EntryTLRef > 0 and (ExitMade = False) and
 (ExitTLRef > 0 or StopLossTLRef > 0) and
 ValidEntryBar and (ValidExitBar or ValidStopLossBar) and
 Close > EntryTLValue and ((ValidExitBar and EntryTLValue > ExitTLValue) or
    (ValidStopLossBar and EntryTLValue > StopLossTLValue)) then
 Buy ("LE1") next bar at market;

{The above statements enter a market order at the open of the next bar if a
current position does not exist (MarketPosition = 0) and a previous exit does
not exist (ExitMade = false) and the current bar closes above the existing
entry trendline (ValidEntryBar) and an exit or stop loss trendline exists
(ValidExitBar or ValidStopLossBar)...(this prevents you from placing an order
to establish a position without first having determined your exit strategy or
placing a stop which in this case are the exit and stop loss trendlines
respectively) and the entry trendline > exit or stop loss trendlines (this
prevents entering a position once an exit or stop loss trendline has
crossed above an entry trendline such as for a triangle pattern).}

if MarketPosition = 1 and ExitTLRef > 0 and ValidExitBar and Close < ExitTLValue then
 begin
 Sell ("LX") next bar at market;
 ExitMade = True;
 end;

{The above statements exit an existing position (MarketPosition = 1) at the open
of the next bar if an exit trendline is valid and the current bar closes below
the exit trendline. This also sets the ExitMade variable to true to prevent
another entry if the strategy is automated.}

if MarketPosition = 1 and StopLossTLRef > 0 and ValidStopLossBar and
 StopLossTLValue < EntryTLValue and Close < StopLossTLValue then
 begin
    Sell ("SL") next bar at market;
 ExitMade = False;
 end;

{The above statements exit an existing position (MarketPosition = 1) at the open
of the next bar if a stop loss trendline is valid and the current bar closes below
the stop loss trendline. This also sets the ExitMade variable to false to allow
another entry if the strategy is automated.}

if MarketPosition = 1 and StopTLRef > 0 and ValidStopBar and
 StopTLValue > EntryTLValue then
    begin
 Sell ("SX") next bar at (StopTLValue) stop;
 ExitMade = True;
 end;

{The above statements place a stop order at the open of the next bar at a valid stop
trendline value if an existing position is established (MarketPosition = 1) and the stop
trendline is above the entry trendline. This also sets the ExitMade variable to true
to prevent another entry if the strategy is automated. The use of this trendline
requires that the beginning point of the trendline is to the right of historical
price bars to prevent a premature exit. It is best to place this trendline once the breakout is confirmed.}

if MarketPosition = 1 and TargetTLRef > 0 and ValidTargetBar then
 begin
 Sell ("TX") next bar at (TargetTLValue) limit;
 ExitMade = True;
 end;

{The above statements place a limit order at the open of the next bar at a valid target trendline value if an existing position is established (MarketPosition = 1). This also sets the ExitMade variable to true to prevent another entry if the strategy is automated. The use of this trendline requires that the beginning point of the trendline is to the right of the entry bar (at a time after the entry bar) to allow another entry if a stop loss is triggered. It is best to place this trendline once the breakout is confirmed.}

Here are the follow up images i mentioned in the first post.

Since my post last week highlightig this trendline strategy and a few requests for the code, I posted them here so that everyone would have it. This is an enhanced version of the strategy I highlighted last week since I added a stop exit option and a target exit option. The code contains explanation comments to help you understand it a bit better. Here are a few key rules:

Either a stop loss or exit trendline has to be established for an entry to trigger. Any of the trendlines can be adjusted before a position is established. For full automation, once an entry is established the entry trendline can't be changed. Once a stop loss has been triggered and a new entry established, neither trendline can be changed. The exit, stop, and target trendlines can be changed as long as the rules shown on the images are followed. They be changed by simply turning the strategy off, moving the trendlines, and turning the strategy back on. Even with the explanation comments and annotation I expect there will be a few questions. This strategy can be best presented with video, but I'm not setup to do that just yet.

I have only live tested the earlier version last week so this one has only been backtested so far. I'll run live tests this week. I also attached a couple of images here to show what an inital setup might look like and what the inital entry looks like. I'll send a follow up with images that show how this would have played out with the 3 exit options. All the images are annotated and I even have a symmetrical pattern measurement included. Since I developed this strategy mostly for trade ideas I used the SWHC trade from the watch list for this example.

I did put in codes that prevent an entry unless a stop or exit trendline exist to be sure good trading practices are followed with this strategy.

To support the professional trading community Matt and Steve have worked so hard to develop I would appreciate this being kept in the BPT membership. Also, if you have any ideas for improving or enhancing this strategy, please let me know. I have the following general plan for future upgrades already: 1) Add a volume option for entry. 2) Add a second target exit option. 3) Add an option to exit a partial postion on the first exit and have stops moved to entry automatically. 4) Have the stop exit option automatically move up to the previous low ( that will be a bit of a challenge). 5) Create the short position version of this long postion strategy.

Matt,

If you've read this far then you don't have any more excuses for missing entries on your own trade ideas, because now you can automate them. LOL!

When I last looked at this I didn't realize that my strategy was limiting maximum trade size to 100,000 shares. I increased the limit to 1,000,000 shares just to see what would happen. With an initial investment of $100,000, the return from 1-1-08 through 5-19-09 without reinvestment is 480%+ and with reinvesting 100% of profits the return increases to 9100%+ (that is $9,100,000 and change). The last trade for this period was on 5-18-09 with a short of 351,270 shares at $23.41 covered at $20.53 for a profit of $1,011,657 on a single trade. The maximum losing trade during this period was on 5-12-09 for a loss of $212,196.